Commit

3 files changed, 123 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000..2380b2e
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,41 @@
+pkgbase = waybar-hyprland
+	pkgdesc = Highly customizable Wayland bar for Sway and Wlroots based compositors, with workspaces support for Hyprland
+	pkgver = 0.9.13
+	pkgrel = 1
+	url = https://github.com/Alexays/Waybar/
+	arch = x86_64
+	license = MIT
+	makedepends = cmake
+	makedepends = catch2
+	makedepends = meson
+	makedepends = scdoc
+	makedepends = wayland-protocols
+	depends = gtkmm3
+	depends = libjsoncpp.so
+	depends = libsigc++
+	depends = fmt
+	depends = wayland
+	depends = libdate-tz.so
+	depends = libspdlog.so
+	depends = gtk-layer-shell
+	depends = libupower-glib.so
+	depends = upower
+	depends = libevdev
+	depends = libpulse
+	depends = libnl
+	depends = libappindicator-gtk3
+	depends = libdbusmenu-gtk3
+	depends = libmpdclient
+	depends = libsndio.so
+	depends = libxkbcommon
+	optdepends = otf-font-awesome: Icons in the default configuration
+	provides = waybar
+	conflicts = waybar
+	backup = etc/xdg/waybar/config
+	backup = etc/xdg/waybar/style.css
+	source = waybar-hyprland-0.9.13.tar.gz::https://github.com/Alexays/Waybar/archive/0.9.13.tar.gz
+	source = https://patch-diff.githubusercontent.com/raw/Alexays/Waybar/pull/1617.patch
+	sha256sums = 9e6553274ce3013d2be9912f975287efe4dfd38de4e335db43a73aff2a3b0a34
+	sha256sums = bedf05c1aeecd9fad517bc91583d3054de97b07e92c63e75220b16f728f10112
+
+pkgname = waybar-hyprland
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 0000000..7e23185
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,6 @@
+/*.zst
+/*.zip
+/*.patch
+/src/
+/pkg/
+/*.gz
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..532cc17
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,76 @@
+# Maintainer: ston <2424284164@qq.com>
+
+pkgname=waybar-hyprland
+pkgver=0.9.13
+pkgrel=1
+pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors, with workspaces support for Hyprland'
+arch=('x86_64')
+url="https://github.com/Alexays/Waybar/"
+license=('MIT')
+provides=('waybar')
+conflicts=('waybar')
+depends=(
+    'gtkmm3'
+    'libjsoncpp.so'
+    'libsigc++'
+    'fmt'
+    'wayland'
+    'libdate-tz.so'
+    'libspdlog.so'
+    'gtk-layer-shell'
+    'libupower-glib.so'
+    'upower'
+    'libevdev'
+    'libpulse'
+    'libnl'
+    'libappindicator-gtk3'
+    'libdbusmenu-gtk3'
+    'libmpdclient'
+    'libsndio.so'
+    'libxkbcommon'
+)
+makedepends=(
+    'cmake'
+    'catch2'
+    'meson'
+    'scdoc' # For generating manpages
+    'wayland-protocols'
+)
+backup=(
+    etc/xdg/waybar/config
+    etc/xdg/waybar/style.css
+)
+optdepends=(
+    'otf-font-awesome: Icons in the default configuration'
+)
+source=(
+    "$pkgname-$pkgver.tar.gz::https://github.com/Alexays/Waybar/archive/$pkgver.tar.gz"
+    "https://patch-diff.githubusercontent.com/raw/Alexays/Waybar/pull/1617.patch"
+)
+sha256sums=('9e6553274ce3013d2be9912f975287efe4dfd38de4e335db43a73aff2a3b0a34'
+            'bedf05c1aeecd9fad517bc91583d3054de97b07e92c63e75220b16f728f10112')
+
+prepare() {
+    cd "Waybar-$pkgver"
+    # Fix fmt 9 compilation issues. This is on master but not yet part of a
+    # release
+    patch -p1 < ../1617.patch
+}
+
+build() {
+    cd "Waybar-$pkgver"
+    meson --prefix=/usr \
+          --buildtype=plain \
+          --auto-features=enabled \
+          --wrap-mode=nodownload \
+          build
+    sed -i 's/zext_workspace_handle_v1_activate(workspace_handle_);/const std::string command = "hyprctl dispatch workspace " + name_;\n\tsystem(command.c_str());/g' src/modules/wlr/workspace_manager.cpp # use hyprctl to switch workspaces
+    meson configure -Dexperimental=true build
+    ninja -C build
+}
+
+package() {
+    cd "Waybar-$pkgver"
+    DESTDIR="$pkgdir" ninja -C build install
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}