# Contributor: Bruno Ancona <bruno at powerball253 dot com>
# Maintainer: Eragon <eragon at eragon dot re>

pkgname=waybar-hyprland-no-systemd
_pkgname=Waybar
pkgver=0.9.20
pkgrel=0
pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors, with workspaces support for Hyprland, without systemd dependency'
arch=('any')
url='https://github.com/Alexays/Waybar/'
license=('MIT')
provides=('waybar')
conflicts=('waybar')
depends=(
    'gtkmm3'
    'libjsoncpp.so'
    'libsigc++'
    'fmt'
    'jack' 'libjack.so'
    'wayland'
    'libdate-tz.so'
    'libspdlog.so'
    'gtk-layer-shell'
    'libupower-glib.so'
    'upower'
    'libevdev'
    'libinput'
    'libpulse'
    'libnl'
    'libappindicator-gtk3'
    'libdbusmenu-gtk3'
    'libmpdclient'
    'libsndio.so'
    'libxkbcommon'
    'wireplumber')
makedepends=(
    'cmake'
    'catch2'
    'meson'
    'scdoc'
    'wayland-protocols')
backup=(
    etc/xdg/waybar/config
    etc/xdg/waybar/style.css)
optdepends=('otf-font-awesome: Icons in the default configuration')
source=("https://github.com/Alexays/Waybar/archive/$pkgver.tar.gz"
        meson-build.patch
        meson_options.patch)
sha256sums=('e300183defece4799b6dfb7aea72400492ec6e330217c22158a334f35532d014'
            '481fb38d459bf1f81725c67e927492940b9f15fd5aeea13d007731c3cee7b749'
            '4592da2c1696f80452b6c2fc7e062bff284c7c186ec0ad120c1417e0377ad8f4')

prepare() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    patch -p1 < ../meson-build.patch
    patch -p1 < ../meson_options.patch
}

build() {
    cd "${srcdir}/${_pkgname}-${pkgver}"

    sed -i 's/zext_workspace_handle_v1_activate(workspace_handle_);/const std::string command = "hyprctl dispatch workspace " + name_;\n\tsystem(command.c_str());/g' src/modules/wlr/workspace_manager.cpp # use hyprctl to switch workspaces
	sed -i '10 i #include <stdexcept>\n#include <string>' include/modules/sway/ipc/client.hpp

    meson --prefix=/usr \
          --buildtype=plain \
          --auto-features=enabled \
          --wrap-mode=nodownload \
          -Dtests=disabled \
          -Dcava=disabled \
          build
    meson configure -Dexperimental=true build
    ninja -C build
}

package() {
    cd "${srcdir}/${_pkgname}-${pkgver}"

    DESTDIR="$pkgdir" ninja -C build install
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}